【MT5/MQL5】インジケータからLINEに簡単通知（ソースあり）

//+------------------------------------------------------------------+
//|                                                  CNotifyLine.mqh |
//|                                  Copyright 2023, MetaQuotes Ltd. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2023, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"

#import "shell32.dll"
int ShellExecuteW(int hWnd,string lpVerb,string lpFile,string lpParameters,string lpDirectory,int nCmdShow);
#import

//+------------------------------------------------------------------+
//|
//| [LINE通知用クラス]
//|
//+------------------------------------------------------------------+
class CNotifyLine
  {
private:

public:
   //|---------------------------------------------------------------+
   //| メンバ変数
   //|---------------------------------------------------------------+
   string            m_curl_path;
   string            m_webhook_url;
   string            m_token;

   //|---------------------------------------------------------------+
   //| コンストラクタ、デストラクタ
   //|---------------------------------------------------------------+
                     CNotifyLine();
                    ~CNotifyLine() {};

   //|---------------------------------------------------------------+
   //| メンバ関数
   //|---------------------------------------------------------------+

   //| curlの実行コマンドパス
   void              CurlPath(string sArgValue) { this.m_curl_path = sArgValue; };

   //| LINEのWebhookURL
   void              WebhookURL(string sArgValue) { this.m_webhook_url = sArgValue; };

   //| LINE Notifyのアクセストークン
   void              Token(string sArgValue) { this.m_token = sArgValue; };

   //| LINE通知実行
   void              Notify(string);

  };

//+------------------------------------------------------------------+
//| [コンストラクタ]
//+------------------------------------------------------------------+
CNotifyLine::CNotifyLine()
  {
   this.m_curl_path="c:\\Windows\\System32\\curl.exe";
   this.m_webhook_url="https://notify-api.line.me/api/notify";
   this.m_token="XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX";
  }

//+------------------------------------------------------------------+
//| [メンバ関数]
//|   LINE通知実行
//+------------------------------------------------------------------+
void CNotifyLine::Notify(string sArgMessage)
  {
   string sCommand;

   StringConcatenate(
      sCommand,
      "/c ",
      this.m_curl_path,
      " -X POST -H \"Authorization: Bearer ",
      this.m_token,
      "\" -F \"",
      "message=",
      sArgMessage,
      "\" ",
      this.m_webhook_url);

   ShellExecuteW(0,"","cmd.exe",sCommand,"",5);
  }
//+------------------------------------------------------------------+

//+------------------------------------------------------------------+
//|                                          IndicatorNotifyLine.mq5 |
//|                                  Copyright 2023, MetaQuotes Ltd. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2023, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property indicator_chart_window

#include "CNotifyLine.mqh"

#property indicator_buffers  1
#property indicator_plots    1

#property indicator_type1    DRAW_LINE
#property indicator_style1   STYLE_SOLID
#property indicator_color1   clrRed
#property indicator_width1   1
double    bufHigh[];

CNotifyLine NotifyLine;

//+------------------------------------------------------------------+
//| 【初期化関数】
//| 　・チャートの初期表示時、または時間足変更等のチャート初期化が必要な
//| 　  タイミングで呼び出される。
//+------------------------------------------------------------------+
int OnInit()
  {
   ArraySetAsSeries(bufHigh, true);
   ArrayInitialize(bufHigh,  0);
   SetIndexBuffer(0,         bufHigh,          INDICATOR_DATA);
   PlotIndexSetDouble(0,     PLOT_EMPTY_VALUE, 0.0);

   return(INIT_SUCCEEDED);
  }

//+------------------------------------------------------------------+
//| 【計算イベント関数】
//| 　・ローソク足に変化が発生する毎に呼び出される。
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {

//+------------------------------------------------------------------+
//| 1. 新規チャートのインジケータ値がまだ計算されていない場合
//| 　　→ 過去チャートのインジケータ値を計算する。
//+------------------------------------------------------------------+
   if(prev_calculated == 0)
     {
      for(int i=rates_total-1; i>=0; i--)
        {
         setBufferValue(i,false);
        }
     }

//+------------------------------------------------------------------+
//| 2. 過去チャートのインジケータ値は計算済で、
//|    前回計算済Bar数 < チャートの最大Bar数 の場合 (Liveで新規Barが発生した)
//| 　　 → 新規Barのインジケータ値を計算する。
//+------------------------------------------------------------------+
   else
     {
      if(prev_calculated < rates_total)
        {
         setBufferValue(0,true);
        }
     }

//+------------------------------------------------------------------+
//| 3. 同Bar内でのティック変更によって呼び出された場合
//| 　 　→ インジケータ値は計算しない
//+------------------------------------------------------------------+

// NOP

//+------------------------------------------------------------------+
//| 今回の処理でインジケータ値を計算したBar数を返却する。
//| 　 → このreturn値は、次回OnCalculate関数が呼び出された際、
//| 　 　 引数のprev_calculatedに設定される。
//+------------------------------------------------------------------+

   return(rates_total);

  }

//+------------------------------------------------------------------+
//| 【インデックスバッファ設定関数】
//| 　・指定されたBar位置のインジケータ値を計算する。
//+------------------------------------------------------------------+
void setBufferValue(int iCurrentBar, bool bIsLiveNewBar)
  {

// 現在Bar位置に、1つ前のBarの高値をプロットする。
   bufHigh[iCurrentBar] = iHigh(Symbol(),PERIOD_CURRENT,iCurrentBar+1);

// Liveで新規Barが発生した場合のみ、LINEでインジケータ値を通知する。
// 過去チャートのインジケータ値を計算している時は通知しない。
   if(bIsLiveNewBar)
     {
      NotifyLine.Notify(DoubleToString(bufHigh[iCurrentBar],5));
     }
  }

//+------------------------------------------------------------------+